' COPY MASK-FIELD VALUES
' © 2004 by Lukasz Szopa, l.szopa@open-document.de
' www.open-document.de

' Das Skript aktiviert sich während der Verschlagwortung einer
' (genauer bestimmter - siehe unten) Maske, und zwar jeweils 
' nachdem ein Maskenfeld VERLASSEN wurde.
' Man kann das Skript entweder manuell aufrufen, oder - wie hier 
' (Elo.ActioKey-Befehle) damit arbeiten, dass es sich beim
' Skript-Aufruf / Ereignis "Beim Bearbeiten der Verschlagwortung"
' Möglich sind auch andere Varianten, wie Ereignisse beim Verschieben 
' aus der Postbox, nach Beendigung eines WF (Schrittes) etc.
' Das Skript funktioniert in allen Archiv-Ansichten (Archiv, Klemmbrett, 
' Postbox, Aufgaben)


Set Elo=CreateObject("ELO.professional")
'set Elo=CreateObject("ELO.office") ' für ELOoffice

MaskNr=Elo.GetObjMaskNo ' Ermittlung der Masken-Nummer                 
ObjektID=Elo.GetEntryID (-1) ' Ermittlung der Objekt-ID


If MaskNr=4 then ' HIER ANPASSEN - entspr. Maskennummer eingeben

' Die Feldinhalt-Übertragung und Änderung der Feldattribute 
' nur für die Maske Nr. 4 durchführen, bei anderen Dokumenten
' soll nichts passieren - weil dort die Feld-Reihenfolge anders ist.


  If Elo.ActionKey=10 or Elo.ActionKey=21 then
  ' wenn das Feld Kurzbezeichnung betreten wird, oder wenn die Maske
  ' mit "OK" verlassen wird, wird das Feld Kurzbezeichnung mit einer
  ' Kombination aus Feld 2 ("Dokuart") + Feld 1 ("Kunde") + Feld2 
  ' ("DokuDatum") gefüllt.

    ' Feldinhalte auslesen...
    Feld1=Elo.GetObjAttrib(0)
    Feld2=Elo.GetObjAttrib(1)
    Feld3=Elo.GetObjAttrib(2)
    
    Kurzbezeichnung=Feld2 & " / " & Feld1 & " / " & Feld3
    Elo.ObjShort=Kurzbezeichnung
  End if


  If Elo.ActionKey=21 or Elo.ActionKey=1004 then
    'Bsp. wenn ein anderes Feld gefüllt werden soll:
    ' Wird gefüllt beim Verlassen der Maske oder beim 
    ' betreten des Feldes 5

    ' Feldinhalte auslesen...
    Feld1=Elo.GetObjAttrib(0)
    Feld2=Elo.GetObjAttrib(1)
    Feld3=Elo.GetObjAttrib(2)

    Feldinhalt4="Dies ist " & Feld2 & " vom " & Feld3 
    Elo.SetObjAttrib 3, Feldinhalt4
  End if    
  

  If Elo.ActionKey=2001 then
    ' Bsp. wenn Feld 2 verlassen wird, und dessen Inhalt = "Rechnung",
    ' dann soll das Feld 3 zu einem Muss-Feld werden:

      If Elo.GetObjAttrib (1)="Rechnung" then 
         Elo.SetObjAttribMin 2,1 ' Mussfeld (min. 1 Zeichen)
      End if 

   End if


End if